A windows batch file to block all applications in a folder in Windows firewall

FirewallBlockAllAppsInFolder.bat

@ setlocal enableextensions 
@ cd /d "%~dp0"
for /R %%a in (*.exe) do (
netsh advfirewall firewall add rule name="Blocked with Batchfile %%a" dir=out program="%%a" action=block
)

this is what you need.

@echo off
setlocal enableextensions
cd /d "%~dp0"

set extensions=.exe .dll .com .bat .cmd .ps1 .vbs .js .py

for %%e in (%extensions%) do (
    for /R %%a in (*%%e) do (
        echo Found: %%a
        call netsh advfirewall firewall add rule name="Blocked %%~nxa (Incoming)" dir=in program="%%a" action=block
        call netsh advfirewall firewall add rule name="Blocked %%~nxa (Outgoing)" dir=out program="%%a" action=block
        echo Blocked: %%a
    )
)

echo Done!
endlocal
pause

This modification is 2x faster, as it doesn't wait for the incoming block to finish, also the reduced echo messages help a bit.

@echo off
cd /d "%~dp0"
set extensions=.exe .dll .com .bat .cmd .ps1 .vbs .js .py
for %%e in (%extensions%) do (  
    for /R %%a in (*%%e) do (
		start /min "" netsh advfirewall firewall add rule name="Blocked %%~nxa (Incoming)" dir=in program="%%a" action=block 
		netsh advfirewall firewall add rule name="Blocked %%~nxa (Outgoing)" dir=out program="%%a" action=block 		>nul
		echo Blocked: %%a
    )
)
echo Done!
pause