https://en.delphipraxis.net/applications/core/interface/file/attachment.php?id=1351 via https://en.delphipraxis.net/topic/1707-rules-for-changing-cursor-to-hourglass-and-back/?tab=comments#comment-13251

hcTemporaryCursor.pas

unit hcTemporaryCursor;

interface

{$I delphi.inc}

uses
  {$ifdef FMX}
     FMX.Platform
    ,FMX.Types
    ,System.UITypes;
  {$else}
    Controls,
    Forms;
  {$endif}

// .NET/C# Equivalent: http://wiert.me/2012/01/26/netc-using-idisposable-to-restore-temporary-settrings-example-temporarycursor-class/

type
  ITemporaryCursor = interface(IInterface)
    ['{495ADE0F-EFBE-4A0E-BF37-F1ACCACCE03D}']
  end;

  TTemporaryCursor = class(TInterfacedObject, ITemporaryCursor)
  {$ifdef DELPHI12_UP}strict {$endif} private
  {$ifdef FMX}
    FCursorService :IFMXCursorService;
  {$endif}
    FCursor: TCursor;
  public
    constructor Create(const ACursor: TCursor);
    destructor Destroy; override;
    class function SetTemporaryCursor(const ACursor: TCursor = crHourGlass): ITemporaryCursor;
  end;

implementation


{ TTemporaryCursor }
constructor TTemporaryCursor.Create(const ACursor: TCursor);
begin
  inherited Create();
  {$ifdef FMX}
  if TPlatformServices.Current.SupportsPlatformService(IFMXCursorService) then
  begin
    FCursorService := TPlatformServices.Current.GetPlatformService(IFMXCursorService) as IFMXCursorService;
    FCursor := FCursorService.GetCursor;
    FCursorService.SetCursor(ACursor);
  end;
  {$else}
  FCursor := Screen.Cursor;
  Screen.Cursor := ACursor;
  {$endif}
end;

destructor TTemporaryCursor.Destroy;
begin
  {$ifdef FMX}
  FCursorService.SetCursor(FCursor);
  {$else}
  if Assigned(Screen) then
  begin
    Screen.Cursor := FCursor;
  end;
  {$endif}
  inherited Destroy();
end;

class function TTemporaryCursor.SetTemporaryCursor(const ACursor: TCursor = crHourGlass): ITemporaryCursor;
begin
  Result := TTemporaryCursor.Create(ACursor);
end;

end.