Cracked PrismLauncher PKGBUILD and compilation steps for ArchLinux (native install :D)

Guide.md

PrismLauncher Offline Mode for ArchLinux

LOC taken from https://github.com/Diegiwg/PrismLauncher-Cracked

You will need to have Git installed at least

1. Download ZIP @ https://gitlab.archlinux.org/archlinux/packaging/packages/prismlauncher
2. Extract ZIP and cd into it
3. Download PKGBUILD from here and replace the one in the repository
4. git clone https://github.com/PrismLauncher/PrismLauncher PrismLauncher-10.0.2
5. cd PrismLauncher-10.0.2 && git tag
6. git checkout tags/10.0.2
7. git submodule update --init --recursive
8. cd ..
9. Open PrismLauncher-10.0.2 in a code editor
10. Open launcher/minecraft/auth/AccountList.cpp
11. Replace:

bool AccountList::anyAccountIsValid()
{
    for (auto account : m_accounts) {
        if (account->ownsMinecraft()) {
            return true;
        }
    }
    return false;
}

With:

bool AccountList::anyAccountIsValid()
{
    return true;
}

12. Open launcher/minecraft/auth/MinecraftAccount.h
13. Replace:

bool ownsMinecraft() const { return data.type != AccountType::Offline && data.minecraftEntitlement.ownsMinecraft; }

With:

bool ownsMinecraft() const { return true; }

14. Finally in the terminal, run makepkg -si and it will be installed!

PKGBUILD

# Maintainer: Giovanni Harting <anonfunc@archlinux.org>
# Contributor: Sefa Eyeoglu <contact@scrumplex.net>
# Contributor: txtsd <aur.archlinux@ihavea.quest>
# Contributor: seth <getchoo at tuta dot io>
# Contributor: Lenny McLennington <lennymclennington@protonmail.com>
# Contributor: Elijah Gregg <lovetocode999@tilde.team>
# Contributor: Miko <mikoxyzzz@gmail.com>
# Contributor: Cheru Berhanu <aur attt cheru doot dev>
# Contributor: dada513 <dada513@protonmail.com>

pkgname=prismlauncher
pkgver=10.0.2
pkgrel=1
pkgdesc="Minecraft launcher with ability to manage multiple instances"
arch=(x86_64)
url='https://prismlauncher.org'
license=('GPL-3.0-only AND LGPL-3.0-or-later AND LGPL-2.0-or-later AND Apache-2.0 AND MIT AND LicenseRef-Batch AND OFL-1.1')
depends=(
  glibc
  mesa-utils
  gcc-libs
  java-runtime
  libarchive
  libgl
  pciutils
  qrencode
  qt6-base
  qt6-imageformats
  qt6-networkauth
  qt6-svg
  zlib
  hicolor-icon-theme
  tomlplusplus
  cmark
)
makedepends=(cmake extra-cmake-modules git jdk17-openjdk ninja scdoc ghc-filesystem gamemode)
optdepends=('glfw: to use system GLFW libraries'
            'openal: to use system OpenAL libraries'
            'visualvm: Profiling support'
            'xorg-xrandr: for older minecraft versions'
            'orca: minecraft screen reader'
            'flite: minecraft voice narration')
source=({lionshead,batch,mdi}.license)
b2sums=('SKIP'
        'SKIP'
        'SKIP')

prepare() {
  ln -sf "$startdir/PrismLauncher-$pkgver" "$srcdir/PrismLauncher-$pkgver"
}

build() {
  cd PrismLauncher-$pkgver

  export PATH="/usr/lib/jvm/java-17-openjdk/bin/:$PATH"

  cmake -DCMAKE_BUILD_TYPE= \
    -GNinja \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DLauncher_BUILD_PLATFORM="archlinux" \
    -DLauncher_QT_VERSION_MAJOR="6" \
    -DLauncher_ENABLE_JAVA_DOWNLOADER=ON \
    -DCMAKE_C_FLAGS="$CFLAGS -DNDEBUG" \
    -DCMAKE_CXX_FLAGS="$CXXFLAGS -DNDEBUG" \
    -Bbuild -S.
  cmake --build build
}

check() {
  cd PrismLauncher-$pkgver/build
  ctest .
}

package() {
  # licenses
  install -Dm644 lionshead.license -t "$pkgdir"/usr/share/licenses/$pkgname/
  install -Dm644 batch.license -t "$pkgdir"/usr/share/licenses/$pkgname/
  install -Dm644 mdi.license -t "$pkgdir"/usr/share/licenses/$pkgname/

  cd PrismLauncher-$pkgver/build
  DESTDIR="$pkgdir" cmake --install .
}

# vim:set ts=2 sw=2 et: